home *** CD-ROM | disk | FTP | other *** search
/ Aminet 30 / Aminet 30 (1999)(Schatztruhe)[!][Apr 1999].iso / Gloom_3 / src / 030_1.s < prev    next >
Text File  |  1997-08-26  |  22KB  |  889 lines
  1.  
  2.         machine 68030
  3.  
  4. NEWCODE EQU 1
  5.  
  6.         bra.w    initc2p     ; offset 0: initialization routines
  7.         bra.w    doc2p_1X8    ; offset 4: one pixel wide version, AGA
  8.         bra.w    doc2p_1X6    ; offset 8: one pixel wide version, EHB
  9.         bra.w    doc2p_2X8    ; offset 12: two pixel wide version, AGA
  10.         bra.w    doc2p_2X6    ; offset 16: two pixel wide version, EHB
  11.         dc.l    string        ; offset 20: address of descr string
  12.  
  13.         dc.b    '$VER: 030_1 1.1 (26/8/97)',0
  14. string        dc.b    'A chunky to planar routine by Peter McGavin. '
  15.         dc.b    'Changes By Iain Barclay. '
  16.         dc.b    'Optimised for 68030. '
  17.         dc.b    'Supports 6/8 bitplane, single/double width pixels.',0
  18.         even
  19.  
  20. initc2p
  21.  
  22. ; create 2 tables for Gloom
  23.  
  24. ; a0=columns buffer to fill in (array of longs) for 1 wide pixs.
  25. ; a1=columns buffer for 2 wide pixs
  26. ; d0=how many columns (multiple of 32)
  27. ; a2=palette remapping array (do 256)
  28.  
  29.         move.w    #255,d1 ;#colours-1
  30. .loop        move.b    d1,(a2,d1.w)
  31.         dbf    d1,.loop
  32.  
  33. ; column offsets for 1 wide pixels
  34.  
  35. ; 0,2,4,6,8,10,12,14,1,3,5,7,9,11,13,15,
  36. ; 16,18,20,...
  37.  
  38.         move.l    d0,d4
  39.         lsr.w    #4,d4
  40.         subq.w    #1,d4
  41.         moveq    #0,d1
  42. .loop0        moveq    #1,d2
  43. .loop1        moveq    #7,d3
  44. .loop2        move.l    d1,(a0)+
  45.         addq.l    #2,d1
  46.         dbf    d3,.loop2
  47.         sub.l    #15,d1
  48.         dbf    d2,.loop1
  49.         add.l    #14,d1
  50.         dbf    d4,.loop0
  51.  
  52. ; column offsets for 2 wide pixels
  53.  
  54. ; 0,4,8,12,1,5,9,13,2,6,10,14,3,7,11,15,
  55. ; 16,20,24,28,17,...
  56.  
  57.         lsr.w    #4,d0
  58.         subq.w    #1,d0
  59.         moveq    #0,d1
  60. .loop3        moveq    #3,d2
  61. .loop4        moveq    #3,d3
  62. .loop5        move.l    d1,(a1)+
  63.         addq.l    #4,d1
  64.         dbf    d3,.loop5
  65.         sub.l    #15,d1
  66.         dbf    d2,.loop4
  67.         add.l    #12,d1
  68.         dbf    d0,.loop3
  69.         rts
  70.  
  71.         cnop    0,4
  72. doc2p_1X8
  73. ; inputs:
  74. ; a0.l=src chunky buffer
  75. ; a1.l=dest chipmem bitmap
  76. ; d0.w=width (in pixels - multiple of 32) to convert
  77. ; d1.w=height (in pixels - even)
  78. ; d2.l=modulo from one bitplane to next (copmod-ish)
  79. ; d3.l=modulo from start of one line to start of next (linemod)
  80.  
  81.         movea.l d2,a5        ; a5 = bpmod
  82.         lsl.l    #3,d2
  83.         sub.l    a5,d2
  84.         subq.l    #2,d2
  85.         movea.l d2,a6        ; a6 = 7*bpmod-2
  86.  
  87.         lsr.w    #4,d0
  88.         ext.l    d0
  89.         move.l    d0,d4
  90.         subq.l    #1,d4
  91.         move.l    d4,-(sp)    ; (4,sp) = num of 16 pix per row - 1
  92.  
  93.         add.l    d0,d0        ; num of 8 pix per row (bytesperrow)
  94.         sub.l    d0,d3
  95.         sub.l    a6,d3
  96.         move.l    d3,-(sp)    ; (sp) = linemod-bytesperrow-7*bpmod+2
  97.  
  98.         move.w    d1,d7
  99.         subq.w    #1,d7        ; d7 = height-1
  100.  
  101.         movea.l #$f0f0f0f0,a2    ; a2 = 4 bit mask
  102.         movea.l #$cccccccc,a3    ; a3 = 2 bit mask
  103.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  104.         movea.l #$aaaa5555,a4    ; a4 = 1 bit mask
  105.  
  106. ;------------------------------------------------------------------------
  107. ;
  108. ; 00        a7a6a5a4a3a2a1a0 i7i6i5i4i3i2i1i0 b7b6b5b4b3b2b1b0 j7j6j5j4j3j2j1j0
  109. ; 01        c7c6c5c4c3c2c1c0 k7k6k5k4k3k2k1k0 d7d6d5d4d3d2d1d0 l7l6l5l4l3l2l1l0
  110. ; 02        e7e6e5e4e3e2e1e0 m7m6m5m4m3m2m1m0 f7f6f5f4f3f2f1f0 n7n6n5n4n3n2n1n0
  111. ; 03        g7g6g5g4g3g2g1g0 o7o6o5o4o3o2o1o0 h7h6h5h4h3h2h1h0 p7p6p5p4p3p2p1p0
  112. ;
  113. ; 10 00x02a a7a6a5a4e7e6e5e4 i7i6i5i4m7m6m5m4 b7b6b5b4f7f6f5f4 j7j6j5j4n7n6n5n4
  114. ; 11 00x02b a3a2a1a0e3e2e1e0 i3i2i1i0m3m2m1m0 b3b2b1b0f3f2f1f0 j3j2j1j0n3n2n1n0
  115. ; 12 01x03a c7c6c5c4g7g6g5g4 k7k6k5k4o7o6o5o4 d7d6d5d4h7h6h5h4 l7l6l5l4p7p6p5p4
  116. ; 13 01x03b c3c2c1c0g3g2g1g0 k3k2k1k0o3o2o1o0 d3d2d1d0h3h2h1h0 l3l2l1l0p3p2p1p0
  117. ;
  118. ; 20 10x12a a7a6c7c6e7e6g7g6 i7i6k7k6m7m6o7o6 b7b6d7d6f7f6h7h6 j7j6l7l6n7n6p7p6
  119. ; 21 10x12b a5a4c5c4e5e4g5g4 i5i4k5k4m5m4o5o4 b5b4d5d4f5f4h5h4 j5j4l5l4n5n4p5p4
  120. ;
  121. ; 30 20x20  a7b7c7d7e7f7g7h7 i7j7k7l7m7n7o7p7 a6b6c6d6e6f6g6h6 i6j6k6l6m6n6o6p6
  122. ; 31 21x21  a5b5c5d5e5f5g5h5 i5j5k5l5m5n5o5p5 a4b4c4d4e4f4g4h4 i4j4k4l4m4n4o4p4
  123. ;
  124. ; 22 11x13a a3a2c3c2e3e2g3g2 i3i2k3k2m3m2o3o2 b3b2d3d2f3f2h3h2 j3j2l3l2n3n2p3p2
  125. ; 23 11x13b a1a0c1c0e1e0g1g0 i1i0k1k0m1m0o1o0 b1b0d1d0f1f0h1h0 j1j0l1l0n1n0p1p0
  126. ;
  127. ; 32 22x22  a3b3c3d3e3f3g3h3 i3j3k3l3m3n3o3p3 a2b2c2d2e2f2g2h2 i2j2k2l2m2n2o2p2
  128. ; 33 23x23  a1b1c1d1e1f1g1h1 i1j1k1l1m1n1o1p1 a0b0c0d0e0f0g0h0 i0j0k0l0m0n0o0p0
  129. ;
  130. ;------------------------------------------------------------------------
  131.  
  132.         swap    d7
  133.         move.w    d4,d7        ; num 16 pix per row - 1
  134.  
  135.         move.l    (a0)+,d0    ; get first 4 pixels 00
  136.         move.l    d0,d4
  137.         move.l    (a0)+,d1    ; get first 4 pixels 01
  138.         and.l    d6,d0
  139.         move.l    (a0)+,d2    ; get first 4 pixels 02
  140.         eor.l    d0,d4
  141.         move.l    (a0)+,d3    ; get first 4 pixels 03
  142.         lsl.l    #4,d4
  143.         bra.b    .same_from_here
  144.  
  145.         cnop    0,4
  146.  
  147. .outerloop    swap    d7
  148.         move.w    (6,sp),d7    ; num 16 pix per row - 1
  149.  
  150.         move.l    (a0)+,d0    ; get 4 next pixels 00
  151.         move.w    d5,(a1)     ; 30 -> plane 6
  152.         move.l    (a0)+,d1    ; get 4 next pixels 01
  153.         swap    d5
  154.         adda.l    a5,a1        ; +bpmod
  155.         move.l    d0,d4
  156.         move.l    (a0)+,d2    ; get 4 next pixels 02
  157.         and.l    d6,d0
  158.         move.l    (a0)+,d3    ; get 4 next pixels 03
  159.         eor.l    d0,d4
  160.         move.w    d5,(a1)     ; 30 -> plane 7
  161.         lsl.l    #4,d4
  162.         adda.l    (sp),a1     ; +linemod-bytesperrow-7*bpmod+2
  163.  
  164.         bra.b    .same_from_here
  165.  
  166.         cnop    0,4
  167. .innerloop    move.l    (a0)+,d0    ; get 4 next pixels 00
  168.         move.w    d5,(a1)     ; 30 -> plane 6
  169.         move.l    d0,d4
  170.         move.l    (a0)+,d1    ; get 4 next pixels 01
  171.         and.l    d6,d0
  172.         adda.l    a5,a1        ; +bpmod
  173.         eor.l    d0,d4
  174.         move.l    (a0)+,d2    ; get 4 next pixels 02
  175.         swap    d5
  176.         move.l    (a0)+,d3    ; get 4 next pixels 03
  177.         lsl.l    #4,d4
  178.         move.w    d5,(a1)     ; 30 -> plane 7
  179.         suba.l    a6,a1        ; - 7 * bpmod + 2
  180. .same_from_here move.l    d2,d5
  181.         and.l    d6,d5
  182.         eor.l    d5,d2
  183.         lsr.l    #4,d5
  184.         or.l    d5,d0
  185.         or.l    d4,d2        ; 00x02 -> 10 11
  186.         move.l    d1,d4
  187.         and.l    d6,d1
  188.         eor.l    d1,d4
  189.         move.l    d3,d5
  190.         and.l    d6,d5
  191.         eor.l    d5,d3
  192.         lsr.l    #4,d5
  193.         lsl.l    #4,d4
  194.         or.l    d5,d1
  195.         or.l    d4,d3        ; 01x03 -> 12 13
  196.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  197.         move.l    d2,d4
  198.         and.l    d6,d2
  199.         eor.l    d2,d4
  200.         move.l    d3,d5
  201.         and.l    d6,d5
  202.         eor.l    d5,d3
  203.         lsl.l    #2,d4
  204.         or.l    d4,d3        ; 11x13b -> 23
  205.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  206.         move.l    d3,d4
  207.         and.l    d6,d3
  208.         eor.l    d3,d4
  209.         lsr.w    #1,d4
  210.         swap    d4
  211.         add.w    d4,d4
  212.         or.l    d4,d3        ; 23x23 -> 33
  213.         move.w    d3,(a1)     ; 33 -> plane 0
  214.         lsr.l    #2,d5
  215.         adda.l    a5,a1        ; +bpmod
  216.         or.l    d5,d2        ; 11x13a -> 22
  217.         move.l    d2,d4
  218.         and.l    d6,d2
  219.         eor.l    d2,d4
  220.         lsr.w    #1,d4
  221.         swap    d3
  222.         move.w    d3,(a1)     ; 33 -> plane 1
  223.         swap    d4
  224.         adda.l    a5,a1        ; +bpmod
  225.         add.w    d4,d4
  226.         or.l    d4,d2        ; 22x22 -> 32
  227.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  228.         move.l    d0,d4
  229.         and.l    d6,d0
  230.         eor.l    d0,d4
  231.         move.w    d2,(a1)     ; 32 -> plane 2
  232.         move.l    d1,d5
  233.         adda.l    a5,a1        ; +bpmod
  234.         and.l    d6,d5
  235.         eor.l    d5,d1
  236.         lsl.l    #2,d4
  237.         or.l    d4,d1        ; 10x12b -> 21
  238.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  239.         swap    d2
  240.         move.w    d2,(a1)     ; 32 -> plane 3
  241.         move.l    d1,d4
  242.         adda.l    a5,a1        ; +bpmod
  243.         and.l    d6,d1
  244.         eor.l    d1,d4
  245.         lsr.w    #1,d4
  246.         swap    d4
  247.         add.w    d4,d4
  248.         or.l    d4,d1        ; 21x21 -> 31
  249.         move.w    d1,(a1)     ; 31 -> plane 4
  250.         lsr.l    #2,d5
  251.         adda.l    a5,a1        ; +bpmod
  252.         or.l    d5,d0        ; 10x12a -> 20
  253.         move.l    d0,d5
  254.         and.l    d6,d0
  255.         eor.l    d0,d5
  256.         swap    d1
  257.         move.w    d1,(a1)     ; 31 -> plane 5
  258.         lsr.w    #1,d5
  259.         adda.l    a5,a1        ; +bpmod
  260.         swap    d5
  261.         add.w    d5,d5
  262.         or.l    d0,d5        ; 20x20 -> 30
  263.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  264.         dbra    d7,.innerloop
  265.  
  266.         swap    d7
  267.         dbra    d7,.outerloop
  268.  
  269.         move.w    d5,(a1)     ; 30 -> plane 6
  270.         adda.l    a5,a1        ; +bpmod
  271.         swap    d5
  272.         move.w    d5,(a1)     ; 30 -> plane 7
  273.         addq.l    #8,sp        ; remove locals
  274.         rts
  275.  
  276.         cnop    0,4
  277. doc2p_1X6
  278. ; inputs:
  279. ; a0.l=src chunky buffer
  280. ; a1.l=dest chipmem bitmap
  281. ; d0.w=width (in pixels - multiple of 32) to convert
  282. ; d1.w=height (in pixels - even)
  283. ; d2.l=modulo from one bitplane to next (copmod-ish)
  284. ; d3.l=modulo from start of one line to start of next (linemod)
  285.  
  286.         movea.l d2,a5        ; a5 = bpmod
  287.         lsl.l    #2,d2
  288.         add.l    a5,d2
  289.         subq.l    #2,d2
  290.         movea.l d2,a6        ; a6 = 5*bpmod-2
  291.  
  292.         lsr.w    #4,d0
  293.         ext.l    d0
  294.         move.l    d0,d4
  295.         subq.l    #1,d4
  296.         move.l    d4,-(sp)    ; (4,sp) = num of 16 pix per row - 1
  297.  
  298.         add.l    d0,d0        ; num of 8 pix per row (bytesperrow)
  299.         sub.l    d0,d3
  300.         sub.l    a6,d3
  301.         move.l    d3,-(sp)    ; (sp) = linemod-bytesperrow-5*bpmod+2
  302.  
  303.         move.w    d1,d7
  304.         subq.w    #1,d7        ; d7 = height-1
  305.  
  306.         movea.l #$f0f0f0f0,a2    ; a2 = 4 bit mask
  307.         movea.l #$cccccccc,a3    ; a3 = 2 bit mask
  308.         movea.l #$aaaa5555,a4    ; a4 = 1 bit mask
  309.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  310.  
  311. ;------------------------------------------------------------------------
  312. ;
  313. ; 00        ....a5a4a3a2a1a0 ....i5i4i3i2i1i0 ....b5b4b3b2b1b0 ....j5j4j3j2j1j0
  314. ; 01        ....c5c4c3c2c1c0 ....k5k4k3k2k1k0 ....d5d4d3d2d1d0 ....l5l4l3l2l1l0
  315. ; 02        ....e5e4e3e2e1e0 ....m5m4m3m2m1m0 ....f5f4f3f2f1f0 ....n5n4n3n2n1n0
  316. ; 03        ....g5g4g3g2g1g0 ....o5o4o3o2o1o0 ....h5h4h3h2h1h0 ....p5p4p3p2p1p0
  317. ;
  318. ; 10 00x02a ....a5a4....e5e4 ....i5i4....m5m4 ....b5b4....f5f4 ....j5j4....n5n4
  319. ; 11 00x02b a3a2a1a0e3e2e1e0 i3i2i1i0m3m2m1m0 b3b2b1b0f3f2f1f0 j3j2j1j0n3n2n1n0
  320. ; 12 01x03a ....c5c4....g5g4 ....k5k4....o5o4 ....d5d4....h5h4 ....l5l4....p5p4
  321. ; 13 01x03b c3c2c1c0g3g2g1g0 k3k2k1k0o3o2o1o0 d3d2d1d0h3h2h1h0 l3l2l1l0p3p2p1p0
  322. ;
  323. ; 21 10x12b a5a4c5c4e5e4g5g4 i5i4k5k4m5m4o5o4 b5b4d5d4f5f4h5h4 j5j4l5l4n5n4p5p4
  324. ;
  325. ; 31 21x21  a5b5c5d5e5f5g5h5 i5j5k5l5m5n5o5p5 a4b4c4d4e4f4g4h4 i4j4k4l4m4n4o4p4
  326. ;
  327. ; 22 11x13a a3a2c3c2e3e2g3g2 i3i2k3k2m3m2o3o2 b3b2d3d2f3f2h3h2 j3j2l3l2n3n2p3p2
  328. ; 23 11x13b a1a0c1c0e1e0g1g0 i1i0k1k0m1m0o1o0 b1b0d1d0f1f0h1h0 j1j0l1l0n1n0p1p0
  329. ;
  330. ; 32 22x22  a3b3c3d3e3f3g3h3 i3j3k3l3m3n3o3p3 a2b2c2d2e2f2g2h2 i2j2k2l2m2n2o2p2
  331. ; 33 23x23  a1b1c1d1e1f1g1h1 i1j1k1l1m1n1o1p1 a0b0c0d0e0f0g0h0 i0j0k0l0m0n0o0p0
  332. ;
  333. ;------------------------------------------------------------------------
  334.  
  335.         swap    d7
  336.         move.w    d4,d7        ; num 16 pix per row - 1
  337.  
  338.         move.l    (a0)+,d0    ; get first 4 pixels 00
  339.         move.l    (a0)+,d1    ; get first 4 pixels 01
  340.         move.l    (a0)+,d2    ; get first 4 pixels 02
  341.         move.l    (a0)+,d3    ; get first 4 pixels 03
  342.  
  343.         move.l    d0,d4
  344.         and.l    d6,d0
  345.         eor.l    d0,d4
  346.         lsl.l    #4,d4
  347.  
  348.         bra.b    .same_from_here
  349.  
  350.         cnop    0,4
  351.  
  352. .outerloop    swap    d7
  353.         move.w    (6,sp),d7    ; num 16 pix per row - 1
  354.  
  355.         move.l    (a0)+,d0    ; get 4 next pixels 00
  356.         move.l    (a0)+,d1    ; get 4 next pixels 01
  357.         move.l    (a0)+,d2    ; get 4 next pixels 02
  358.         move.l    (a0)+,d3    ; get 4 next pixels 03
  359.  
  360.         move.w    d5,(a1)     ; 31 -> plane 4
  361.         adda.l    a5,a1        ; +bpmod
  362.  
  363.         move.l    d0,d4
  364.         and.l    d6,d0
  365.         eor.l    d0,d4
  366.         lsl.l    #4,d4
  367.  
  368.         swap    d5
  369.         move.w    d5,(a1)     ; 31 -> plane 5
  370.         adda.l    (sp),a1     ; +linemod-bytesperrow-5*bpmod+2
  371.  
  372.         bra.b    .same_from_here
  373.  
  374.         cnop    0,4
  375. .innerloop    move.l    (a0)+,d0    ; get 4 next pixels 00
  376.         move.l    (a0)+,d1    ; get 4 next pixels 01
  377.         move.l    (a0)+,d2    ; get 4 next pixels 02
  378.         move.l    (a0)+,d3    ; get 4 next pixels 03
  379.  
  380.         move.w    d5,(a1)     ; 31 -> plane 4
  381.         adda.l    a5,a1        ; +bpmod
  382.  
  383.         move.l    d0,d4
  384.         and.l    d6,d0
  385.         eor.l    d0,d4
  386.         lsl.l    #4,d4
  387.  
  388.         swap    d5
  389.         move.w    d5,(a1)     ; 31 -> plane 5
  390.         suba.l    a6,a1        ; -5*bpmod+2
  391.  
  392. .same_from_here move.l    d2,d5
  393.         and.l    d6,d5
  394.         eor.l    d5,d2
  395.         lsr.l    #4,d5
  396.         or.l    d5,d0
  397.         or.l    d4,d2        ; 00x02 -> 10 11
  398.         move.l    d1,d4
  399.         and.l    d6,d1
  400.         eor.l    d1,d4
  401.         move.l    d3,d5
  402.         and.l    d6,d5
  403.         eor.l    d5,d3
  404.         lsr.l    #4,d5
  405.         lsl.l    #4,d4
  406.         or.l    d5,d1
  407.         or.l    d4,d3        ; 01x03 -> 12 13
  408.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  409.         move.l    d2,d4
  410.         and.l    d6,d2
  411.         eor.l    d2,d4
  412.         move.l    d3,d5
  413.         and.l    d6,d5
  414.         eor.l    d5,d3
  415.         lsl.l    #2,d4
  416.         or.l    d4,d3        ; 11x13b -> 23
  417.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  418.         move.l    d3,d4
  419.         and.l    d6,d3
  420.         eor.l    d3,d4
  421.         lsr.w    #1,d4
  422.         swap    d4
  423.         add.w    d4,d4
  424.         or.l    d4,d3        ; 23x23 -> 33
  425.  
  426.         move.w    d3,(a1)     ; 33 -> plane 0
  427.         adda.l    a5,a1        ; +bpmod
  428.  
  429.         lsr.l    #2,d5
  430.         or.l    d5,d2        ; 11x13a -> 22
  431.         move.l    d2,d4
  432.         and.l    d6,d2
  433.         eor.l    d2,d4
  434.  
  435.         swap    d3
  436.         move.w    d3,(a1)     ; 33 -> plane 1
  437.         adda.l    a5,a1        ; +bpmod
  438.  
  439.         lsr.w    #1,d4
  440.         swap    d4
  441.         add.w    d4,d4
  442.         or.l    d4,d2        ; 22x22 -> 32
  443.         lsl.l    #2,d0
  444.  
  445.         move.w    d2,(a1)     ; 32 -> plane 2
  446.         adda.l    a5,a1        ; +bpmod
  447.  
  448.         or.l    d0,d1        ; 10x12b -> 21
  449.         swap    d2
  450.         move.l    d1,d5
  451.         and.l    d6,d1
  452.         eor.l    d1,d5
  453.  
  454.         move.w    d2,(a1)     ; 32 -> plane 3
  455.         adda.l    a5,a1        ; +bpmod
  456.  
  457.         lsr.w    #1,d5
  458.         swap    d5
  459.         add.w    d5,d5
  460.         or.l    d1,d5        ; 21x21 -> 31
  461.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  462.  
  463.         dbra    d7,.innerloop
  464.  
  465.         swap    d7
  466.         dbra    d7,.outerloop
  467.  
  468.         move.w    d5,(a1)     ; 31 -> plane 4
  469.         adda.l    a5,a1        ; +bpmod
  470.         swap    d5
  471.         move.w    d5,(a1)     ; 31 -> plane 5
  472.         addq.l    #8,sp        ; remove locals
  473.         rts
  474.  
  475.         cnop    0,4
  476. doc2p_2X8
  477. ; inputs:
  478. ; a0.l=src chunky buffer
  479. ; a1.l=dest chipmem bitmap
  480. ; d0.w=width (in pixels - multiple of 32) to convert
  481. ; d1.w=height (in pixels - even)
  482. ; d2.l=modulo from one bitplane to next (copmod-ish)
  483. ; d3.l=modulo from start of one line to start of next (linemod)
  484.  
  485.         movea.l d2,a6        ; a6 = bpmod
  486.         move.l    d2,d4
  487.         lsl.l    #3,d4
  488.         sub.l    d2,d4
  489.         neg.l    d4
  490.         addq.l    #4,d4
  491.         movea.l d4,a3        ; a3 = -7*bpmod+4
  492.         movea.l d4,a4        ; a4 = -7*bpmod+4
  493.         lsr.w    #4,d0
  494.         movea.w d0,a2
  495.         subq.l    #1,a2        ; a2 = num 16 pix per row - 1
  496.         lsl.w    #2,d0        ; d0 = num 4 pix per row (bytesperrow)
  497.         movea.l d3,a5
  498.         suba.w    d0,a5
  499.         adda.l    a3,a5        ; a5 = linemod-bytesperrow-7*bpmod+4
  500.         move.w    d1,d7
  501.         subq.w    #1,d7        ; d7 = height - 1
  502.  
  503. ;------------------------------------------------------------------------
  504. ; original pixels
  505. ; 00        a7a6a5a4a3a2a1a0 e7e6e5e4e3e2e1e0 i7i6i5i4i3i2i1i0 m7m6m5m4m3m2m1m0
  506. ; 01        b7b6b5b4b3b2b1b0 f7f6f5f4f3f2f1f0 j7j6j5j4j3j2j1j0 n7n6n5n4n3n2n1n0
  507. ; 02        c7c6c5c4c3c2c1c0 g7g6g5g4g3g2g1g0 k7k6k5k4k3k2k1k0 o7o6o5o4o3o2o1o0
  508. ; 03        d7d6d5d4d3d2d1d0 h7h6h5h4h3h2h1h0 l7l6l5l4l3l2l1l0 p7p6p5p4p3p2p1p0
  509. ;
  510. ; after 4bit merge
  511. ; 10 00x02a a7a6a5a4c7c6c5c4 e7e6e5e4g7g6g5g4 i7i6i5i4k7k6k5k4 m7m6m5m4o7o6o5o4
  512. ; 11 00x02b a3a2a1a0c3c2c1c0 e3e2e1e0g3g2g1g0 i3i2i1i0k3k2k1k0 m3m2m1m0o3o2o1o0
  513. ; 12 01x03a b7b6b5b4d7d6d5d4 f7f6f5f4h7h6h5h4 j7j6j5j4l7l6l5l4 n7n6n5n4p7p6p5p4
  514. ; 13 01x03b b3b2b1b0d3d2d1d0 f3f2f1f0h3h2h1h0 j3j2j1j0l3l2l1l0 n3n2n1n0p3p2p1p0
  515. ;
  516. ; after 2bit merge
  517. ; 20 10x12a a7a6b7b6c7c6d7d6 e7e6f7f6g7g6h7h6 i7i6j7j6k7k6l7l6 m7m6n7n6o7o6p7p6
  518. ; 21 10x12b a5a4b5b4c5c4d5d4 e5e4f5f4g5g4h5h4 i5i4j5j4k5k4l5l4 m5m4n5n4o5o4p5p4
  519. ; 22 11x13a a3a2b3b2c3c2d3d2 e3e2f3f2g3g2h3h2 i3i2j3j2k3k2l3l2 m3m2n3n2o3o2p3p2
  520. ; 23 11x13b a1a0b1b0c1c0d1d0 e1e0f1f0g1g0h1h0 i1i0j1j0k1k0l1l0 m1m0n1n0o1o0p1p0
  521. ;
  522. ; after 1bit merge
  523. ; 30 20x20a a7a7b7b7c7c7d7d7 e7e7f7f7g7g7h7h7 i7i7j7j7k7k7l7l7 m7m7n7n7o7o7p7p7
  524. ; 31 20x20b a6a6b6b6c6c6d6d6 e6e6f6f6g6g6h6h6 i6i6j6j6k6k6l6l6 m6m6n6n6o6o6p6p6
  525. ; 32 21x21a a5a5b5b5c5c5d5d5 e5e5f5f5g5g5h5h5 i5i5j5j5k5k5l5l5 m5m5n5n5o5o5p5p5
  526. ; 33 21x21b a4a4b4b4c4c4d4d4 e4e4f4f4g4g4h4h4 i4i4j4j4k4k4l4l4 m4m4n4n4o4o4p4p4
  527. ; 34 22x22a a3a3b3b3c3c3d3d3 e3e3f3f3g3g3h3h3 i3i3j3j3k3k3l3l3 m3m3n3n3o3o3p3p3
  528. ; 35 22x22b a2a2b2b2c2c2d2d2 e2e2f2f2g2g2h2h2 i2i2j2j2k2k2l2l2 m2m2n2n2o2o2p2p2
  529. ; 36 23x23a a1a1b1b1c1c1d1d1 e1e1f1f1g1g1h1h1 i1i1j1j1k1k1l1l1 m1m1n1n1o1o1p1p1
  530. ; 37 23x23b a0a0b0b0c0c0d0d0 e0e0f0f0g0g0h0h0 i0i0j0j0k0k0l0l0 m0m0n0n0o0o0p0p0
  531. ;------------------------------------------------------------------------
  532.  
  533.         swap    d7
  534.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  535.  
  536.         move.l    (a0)+,d0    ; read first 12 (game) pixels
  537.         move.l    (a0)+,d1
  538.         move.l    (a0)+,d2
  539.         move.l    #$f0f0f0f0,d6
  540.  
  541.         move.l    d0,d4
  542.         move.l    d2,d5
  543.         and.l    d6,d0        ; #$f0f0f0f0
  544.         eor.l    d0,d4
  545.         lsl.l    #4,d4
  546.         and.l    d6,d5        ; #$f0f0f0f0
  547.         eor.l    d5,d2
  548.         lsr.l    #4,d5
  549.         or.l    d5,d0
  550.         or.l    d4,d2        ; 00x02 -> 10 11
  551.  
  552.         bra    .same_from_here
  553.  
  554.         cnop    0,4
  555.  
  556. .outerloop    swap    d7
  557.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  558.  
  559. .innerloop    move.l    (a0)+,d0    ; read next 12 (game) pixels
  560.         move.l    (a0)+,d1
  561.         move.l    (a0)+,d2
  562.         move.l    d6,(a1)     ; 32 -> plane 5
  563.         adda.l    a6,a1        ; +bpmod
  564.  
  565.         move.l    #$f0f0f0f0,d6
  566.  
  567.         move.l    d0,d4
  568.         and.l    d6,d0        ; #$f0f0f0f0
  569.         eor.l    d0,d4
  570.         lsl.l    #4,d4
  571.  
  572.         move.l    d5,(a1)     ; 31 -> plane 6
  573.         adda.l    a6,a1        ; +bpmod
  574.  
  575.         move.l    d2,d5
  576.         and.l    d6,d5        ; #$f0f0f0f0
  577.         eor.l    d5,d2
  578.         lsr.l    #4,d5
  579.         or.l    d5,d0
  580.         or.l    d4,d2        ; 00x02 -> 10 11
  581.  
  582.         move.l    d3,(a1)     ; 30 -> plane 7
  583.         adda.l    a4,a1        ; -7*bpmod+4 or
  584.                     ; +linemod-bytesperrow-7*bpmod+4
  585.  
  586. .same_from_here move.l    d1,d4
  587.         and.l    d6,d1        ; #$f0f0f0f0
  588.         eor.l    d1,d4
  589.         lsl.l    #4,d4
  590.  
  591.         move.l    (a0)+,d3    ; read next 4 (game) pixels
  592.  
  593.         move.l    d3,d5
  594.         and.l    d6,d5        ; #$f0f0f0f0
  595.         eor.l    d5,d3
  596.         lsr.l    #4,d5
  597.         or.l    d5,d1
  598.         or.l    d4,d3        ; 01x03 -> 12 13
  599.  
  600.         move.l    #$cccccccc,d6
  601.  
  602.         move.l    d0,d4
  603.         and.l    d6,d0        ; #$cccccccc
  604.         eor.l    d0,d4
  605.         lsl.l    #2,d4
  606.         move.l    d1,d5
  607.         and.l    d6,d5        ; #$cccccccc
  608.         eor.l    d5,d1
  609.         lsr.l    #2,d5
  610.         or.l    d5,d0
  611.         or.l    d4,d1        ; 10x12 -> 20 21
  612.  
  613.         move.l    d2,d4
  614.         and.l    d6,d2        ; #$cccccccc
  615.         eor.l    d2,d4
  616.         lsl.l    #2,d4
  617.         move.l    d3,d5
  618.         and.l    d6,d5        ; #$cccccccc
  619.         eor.l    d5,d3
  620.         lsr.l    #2,d5
  621.         or.l    d5,d2
  622.         or.l    d4,d3        ; 11x13 -> 22 23
  623.  
  624.         move.l    #$aaaaaaaa,d6
  625.  
  626.         move.l    d3,d4
  627.         and.l    d6,d3        ; #$aaaaaaaa
  628.         eor.l    d3,d4
  629.  
  630.         move.l    d4,d5
  631.         add.l    d4,d4
  632.         or.l    d4,d5        ; 23x23b -> 37
  633.  
  634.         move.l    d5,(a1)     ; 37 -> plane 0
  635.         adda.l    a6,a1        ; +bpmod
  636.  
  637.         move.l    d3,d4
  638.         lsr.l    #1,d3
  639.         or.l    d3,d4        ; 23x23a -> 36
  640.         move.l    d2,d5
  641.         and.l    d6,d2        ; #$aaaaaaaa
  642.         eor.l    d2,d5
  643.  
  644.         move.l    d4,(a1)     ; 36 -> plane 1
  645.         adda.l    a6,a1        ; +bpmod
  646.  
  647.         move.l    d5,d3
  648.         add.l    d5,d5
  649.         or.l    d5,d3        ; 22x22b -> 35
  650.         move.l    d2,d5
  651.         lsr.l    #1,d2
  652.         or.l    d5,d2        ; 22x22a -> 34
  653.  
  654.         move.l    d3,(a1)     ; 35 -> plane 2
  655.         adda.l    a6,a1        ; +bpmod
  656.  
  657.         move.l    d1,d4
  658.         and.l    d6,d1        ; #$aaaaaaaa
  659.         eor.l    d1,d4
  660.         move.l    d0,d5
  661.         and.l    d6,d0        ; #$aaaaaaaa
  662.         eor.l    d0,d5
  663.  
  664.         move.l    d2,(a1)     ; 34 -> plane 3
  665.         adda.l    a6,a1        ; +bpmod
  666.  
  667.         move.l    d4,d2
  668.         add.l    d4,d4
  669.         or.l    d4,d2        ; 21x21b -> 33
  670.         move.l    d1,d6
  671.         lsr.l    #1,d1
  672.         or.l    d1,d6        ; 21x21a -> 32
  673.         move.l    d5,d3
  674.  
  675.         move.l    d2,(a1)     ; 33 -> plane 4
  676.         adda.l    a6,a1        ; +bpmod
  677.  
  678.         add.l    d5,d5
  679.         or.l    d3,d5        ; 20x20b -> 31
  680.         move.l    d0,d3
  681.         lsr.l    #1,d0
  682.         or.l    d0,d3        ; 20x20a -> 30
  683.  
  684.         movea.l a3,a4        ; a4 = -7*bpmod+4
  685.  
  686.         dbra    d7,.innerloop
  687.  
  688.         movea.l a5,a4        ; a4 = linemod-bytesperrow-7*bpmod+4
  689.  
  690.         swap    d7
  691.         dbra    d7,.outerloop
  692.  
  693.         move.l    d6,(a1)     ; 32 -> plane 5
  694.         adda.l    a6,a1        ; +bpmod
  695.         move.l    d5,(a1)     ; 31 -> plane 6
  696.         adda.l    a6,a1        ; +bpmod
  697.         move.l    d3,(a1)     ; 30 -> plane 7
  698.         rts
  699.  
  700.         cnop    0,4
  701. doc2p_2X6
  702. ; inputs:
  703. ; a0.l=src chunky buffer
  704. ; a1.l=dest chipmem bitmap
  705. ; d0.w=width (in pixels - multiple of 32) to convert
  706. ; d1.w=height (in pixels - even)
  707. ; d2.l=modulo from one bitplane to next (copmod-ish)
  708. ; d3.l=modulo from start of one line to start of next (linemod)
  709.  
  710.         movea.l d2,a6        ; a6 = bpmod
  711.         move.l    d2,d4
  712.         lsl.l    #2,d4
  713.         add.l    d2,d4
  714.         neg.l    d4
  715.         addq.l    #4,d4
  716.         movea.l d4,a3        ; a3 = -5*bpmod+4
  717.         movea.l d4,a4        ; a4 = -5*bpmod+4
  718.         lsr.w    #4,d0
  719.         movea.w d0,a2
  720.         subq.l    #1,a2        ; a2 = num 16 pix per row - 1
  721.         lsl.w    #2,d0        ; d0 = num 4 pix per row (bytesperrow)
  722.         movea.l d3,a5
  723.         suba.w    d0,a5
  724.         adda.l    a3,a5        ; a5 = linemod-bytesperrow-5*bpmod+4
  725.         move.w    d1,d7
  726.         subq.w    #1,d7        ; d7 = height - 1
  727.  
  728. ;------------------------------------------------------------------------
  729. ; original pixels
  730. ; 00        ....a5a4a3a2a1a0 ....e5e4e3e2e1e0 ....i5i4i3i2i1i0 ....m5m4m3m2m1m0
  731. ; 01        ....b5b4b3b2b1b0 ....f5f4f3f2f1f0 ....j5j4j3j2j1j0 ....n5n4n3n2n1n0
  732. ; 02        ....c5c4c3c2c1c0 ....g5g4g3g2g1g0 ....k5k4k3k2k1k0 ....o5o4o3o2o1o0
  733. ; 03        ....d5d4d3d2d1d0 ....h5h4h3h2h1h0 ....l5l4l3l2l1l0 ....p5p4p3p2p1p0
  734. ;
  735. ; after 4bit merge
  736. ; 10 00x02a ....a5a4....c5c4 ....e5e4....g5g4 ....i5i4....k5k4 ....m5m4....o5o4
  737. ; 11 00x02b a3a2a1a0c3c2c1c0 e3e2e1e0g3g2g1g0 i3i2i1i0k3k2k1k0 m3m2m1m0o3o2o1o0
  738. ; 12 01x03a ....b5b4....d5d4 ....f5f4....h5h4 ....j5j4....l5l4 ....n5n4....p5p4
  739. ; 13 01x03b b3b2b1b0d3d2d1d0 f3f2f1f0h3h2h1h0 j3j2j1j0l3l2l1l0 n3n2n1n0p3p2p1p0
  740. ;
  741. ; after 2bit merge
  742. ; 21 10x12b a5a4b5b4c5c4d5d4 e5e4f5f4g5g4h5h4 i5i4j5j4k5k4l5l4 m5m4n5n4o5o4p5p4
  743. ; 22 11x13a a3a2b3b2c3c2d3d2 e3e2f3f2g3g2h3h2 i3i2j3j2k3k2l3l2 m3m2n3n2o3o2p3p2
  744. ; 23 11x13b a1a0b1b0c1c0d1d0 e1e0f1f0g1g0h1h0 i1i0j1j0k1k0l1l0 m1m0n1n0o1o0p1p0
  745. ;
  746. ; after 1bit merge
  747. ; 32 21x21a a5a5b5b5c5c5d5d5 e5e5f5f5g5g5h5h5 i5i5j5j5k5k5l5l5 m5m5n5n5o5o5p5p5
  748. ; 33 21x21b a4a4b4b4c4c4d4d4 e4e4f4f4g4g4h4h4 i4i4j4j4k4k4l4l4 m4m4n4n4o4o4p4p4
  749. ; 34 22x22a a3a3b3b3c3c3d3d3 e3e3f3f3g3g3h3h3 i3i3j3j3k3k3l3l3 m3m3n3n3o3o3p3p3
  750. ; 35 22x22b a2a2b2b2c2c2d2d2 e2e2f2f2g2g2h2h2 i2i2j2j2k2k2l2l2 m2m2n2n2o2o2p2p2
  751. ; 36 23x23a a1a1b1b1c1c1d1d1 e1e1f1f1g1g1h1h1 i1i1j1j1k1k1l1l1 m1m1n1n1o1o1p1p1
  752. ; 37 23x23b a0a0b0b0c0c0d0d0 e0e0f0f0g0g0h0h0 i0i0j0j0k0k0l0l0 m0m0n0n0o0o0p0p0
  753. ;------------------------------------------------------------------------
  754.  
  755.         swap    d7
  756.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  757.         move.l    (a0)+,d0    ; read first 12 (game) pixels
  758.         move.l    (a0)+,d1
  759.         move.l    (a0)+,d2
  760.         move.l    #$f0f0f0f0,d6
  761.         move.l    d0,d4
  762.         move.l    d2,d5
  763.         and.l    d6,d0        ; #$f0f0f0f0
  764.         eor.l    d0,d4
  765.         lsl.l    #4,d4
  766.         and.l    d6,d5        ; #$f0f0f0f0
  767.         eor.l    d5,d2
  768.         lsr.l    #4,d5
  769.         or.l    d5,d0
  770.         or.l    d4,d2        ; 00x02 -> 10 11
  771.  
  772.         move.l    d1,d4
  773.         and.l    d6,d1
  774.         eor.l    d1,d4
  775.         lsl.l    #4,d4
  776.         move.l    (a0)+,d3    ; read next 4
  777.         move.l    d3,d5
  778.         and.l    d6,d5
  779.         eor.l    d5,d3
  780.         lsr.l    #4,d5
  781.         or.l    d5,d1
  782.         or.l    d4,d3
  783.         lsl.l    #2,d0
  784.         or.l    d0,d1
  785.         move.l    d2,d4
  786.         move.l    #$cccccccc,d6
  787.         and.l    d6,d2
  788.         eor.l    d2,d4
  789.         lsl.l    #2,d4
  790.         bra    .same_from_here
  791.  
  792.         cnop    0,4
  793.  
  794. .outerloop    swap    d7
  795.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  796.  
  797. .innerloop    move.l    (a0)+,d0    ; read next 12 (game) pixels
  798.         move.l    (a0)+,d1
  799.         move.l    (a0)+,d2
  800.         move.l    d5,(a1)     ; 34 -> plane 3
  801.         adda.l    a6,a1        ; +bpmod
  802.         move.l    #$f0f0f0f0,d6
  803.         move.l    d0,d4
  804.         and.l    d6,d0
  805.         eor.l    d0,d4
  806.         lsl.l    #4,d4
  807.         move.l    d2,d5
  808.         and.l    d6,d5
  809.         eor.l    d5,d2
  810.         lsr.l    #4,d5
  811.         or.l    d5,d0
  812.         or.l    d4,d2
  813.         move.l    d1,d4
  814.         and.l    d6,d1
  815.         move.l    d3,(a1)     ; 33 -> plane 4
  816.         adda.l    a6,a1        ; +bpmod
  817.         eor.l    d1,d4
  818.         lsl.l    #4,d4
  819.         move.l    (a0)+,d3
  820.         move.l    d3,d5
  821.         and.l    d6,d5
  822.         eor.l    d5,d3
  823.         lsr.l    #4,d5
  824.         or.l    d5,d1
  825.         or.l    d4,d3
  826.         lsl.l    #2,d0
  827.         or.l    d0,d1
  828.         move.l    d2,d4
  829.         move.l    #$cccccccc,d6
  830.         and.l    d6,d2
  831.         eor.l    d2,d4
  832.         lsl.l    #2,d4
  833.         move.l    d6,(a1)
  834.         adda.l    a4,a1
  835. .same_from_here
  836.         move.l    d3,d5
  837.         and.l    d6,d5
  838.         eor.l    d5,d3
  839.         lsr.l    #2,d5
  840.         or.l    d5,d2
  841.         or.l    d4,d3
  842.         move.l    d3,d4
  843.         move.l    #$aaaaaaaa,d6
  844.         and.l    d6,d3
  845.         eor.l    d3,d4
  846.         move.l    d4,d5
  847.         add.l    d4,d4
  848.         or.l    d4,d5
  849.         move.l    d5,(a1)
  850.         adda.l    a6,a1
  851.         move.l    d3,d4
  852.         lsr.l    #1,d3
  853.         or.l    d3,d4
  854.         move.l    d2,d5
  855.         and.l    d6,d2
  856.         eor.l    d2,d5
  857.         move.l    d5,d6
  858.         add.l    d5,d5
  859.         move.l    d4,(a1)
  860.         adda.l    a6,a1
  861.         or.l    d5,d6
  862.         move.l    d2,d5
  863.         lsr.l    #1,d2
  864.         or.l    d2,d5
  865.         move.l    d1,d4
  866.         and.l    #$aaaaaaaa,d1
  867.         eor.l    d1,d4
  868.         move.l    d4,d3
  869.         move.l    d6,(a1)
  870.         adda.l    a6,a1
  871.         add.l    d4,d4
  872.         or.l    d4,d3
  873.         move.l    d1,d6
  874.         lsr.l    #1,d6
  875.         or.l    d1,d6
  876.         move.l    a3,a4
  877.         dbra    d7,.innerloop
  878.         move.l    a5,a4
  879.         swap    d7
  880.         dbra    d7,.outerloop
  881.         move.l    d5,(a1)
  882.         adda.l    a6,a1
  883.         move.l    d3,(a1)
  884.         adda.l    a6,a1
  885.         move.l    d6,(a1)
  886.         rts
  887.  
  888.         end
  889.